_pkgbase=boost
pkgname=boost-doc
pkgver=1.74.0
_boostver=${pkgver//./_}
pkgrel=1
pkgdesc='Free peer-reviewed portable C++ source libraries (HTML documentation)'
url='https://www.boost.org/'
arch=('x86_64')
license=('custom')
makedepends=()
source=(https://dl.bintray.com/boostorg/release/${pkgver}/source/boost_${_boostver}.tar.bz2)
sha256sums=('83bfc1507731a0906e387fc28b7ef5417d591429e51e788417fe9ff025e116b1')
options=(!strip)

package() {
   cd ${_pkgbase}_${_boostver}
   local dest=$pkgdir/usr/share/$_pkgbase/doc

   install -dm755 "$dest"
   find \( \
      -iname '*.htm' -o -iname '*.html' -o -iname '*.css' -o \
      -iname '*.png' -o -iname '*.gif' -o -iname '*.jpg' -o -iname '*.js' \
   \) -exec cp --target-directory="$dest" --parents --verbose {} +
}

# vim: ts=2 sw=2 et:
