# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Tom Gundersen <teg@jklm.no>
# Contributor: John Proctor <jproctor@prium.net>

_pkgname=libxml2
pkgname=static-compat-$_pkgname
pkgver=2.10.3
pkgrel=2
pkgdesc='XML C parser and toolkit'
url='https://gitlab.gnome.org/GNOME/libxml2/-/wikis/home'
arch=(x86_64)
license=(MIT)
depends=(static-compat-zlib static-compat-xz)
makedepends=(git static-compat-configure python)
options=(!emptydirs staticlibs)
_commit=f507d167f1755b7eaea09fb1a44d29aab828b6d1  # tags/v2.10.3^0
source=("git+https://gitlab.gnome.org/GNOME/libxml2.git#commit=$_commit"
        libxml2-2.9.8-python3-unicode-errors.patch
        no-fuzz.diff
        https://www.w3.org/XML/Test/xmlts20130923.tar.gz)
sha256sums=('SKIP'
            '3d07a50fc0963bda05fc5269dedc51f108260699e25e455bb31f6d80c2a9cada'
            '3908e7a53b20109bdfde143238f36e22a154dbb7d363b634e54c0a18328f4656'
            '9b61db9f5dbffa545f4b8d78422167083a8568c59bd1129f94138f936cf6fc1f')

pkgver() {
  cd libxml2
  git describe --tags | sed 's/-rc/rc/;s/^v//;s/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  source static-compat-environment
  cd libxml2
  mkdir build
  ln -s ../xmlconf

  # https://src.fedoraproject.org/rpms/libxml2/tree/rawhide
  git apply -3 ../libxml2-2.9.8-python3-unicode-errors.patch

  # Do not run fuzzing tests
  git apply -3 ../no-fuzz.diff

  NOCONFIGURE=1 ./autogen.sh
}

build() (
  source static-compat-environment
  export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:/usr/lib/pkgconfig  # for Python
  cd libxml2/build

  static-compat-configure \
    --disable-shared \
    --enable-static \
    --with-threads \
    --without-history \
    --without-icu \
    --without-docbook \
    --without-html
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' libtool
  make
)

#check() {
#  source static-compat-environment
#  make -C libxml2/build check
#}

package() {
  source static-compat-environment
  make -C libxml2/build DESTDIR="$pkgdir" install
  rm -r "$pkgdir/$static_compat_prefix"/{bin,share/man,share/doc,share/gtk-doc}
  install -Dm644 "$srcdir/libxml2/Copyright" -t "$pkgdir/usr/share/licenses/$pkgname"
}

# vim: ts=2 sw=2 et:
