PKGBUILDs/tageditor/git/PKGBUILD

# Maintainer: Martchus <martchus@gmx.net>
# decide whether to link against the deprecated Qt WebKit module (in qt5-webkit package ~40 MB) or
# the newer, chromium-based Qt WebEngine module (in qt5-webengine package ~100 MB)
_webviewprovider=qt5-webkit
_name=tageditor
pkgname=tageditor-git
pkgver=66.77a0bc2
pkgrel=11
arch=('i686' 'x86_64')
pkgdesc="A tag editor with Qt GUI and command-line interface supporting MP4 (iTunes), ID3, Vorbis and Matroska (git version)."
license=('GPL')
depends=('qt5-script' $_webviewprovider 'qtutilities' 'tagparser' 'desktop-file-utils' 'xdg-utils')
makedepends=('qt5-tools' 'git')
provides=('tageditor')
conflicts=('tageditor')
install=${_name}.install
url="https://github.com/Martchus/tageditor"
source=("${pkgname}::git://github.com/Martchus/tageditor.git")
_reponame=tageditor
sha256sums=('SKIP')

pkgver() {
    cd "${srcdir}/${pkgname}"
    echo "$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

build() {
    cd "${srcdir}/${pkgname}"
    cfg=()
    if [[ _webviewprovider == qt5-webkit ]]; then
        cfg+=(forcewebkit)
    fi
    INSTALL_ROOT=$pkgdir/usr/ qmake-qt5 "$_name.pro" $(for val in "${cfg[@]}"; do echo -n "CONFIG+=$val "; done)
    make
}

package() {
    cd "${srcdir}/${pkgname}"
    make install
}