Add reflective-rapidjson-git

reflective-rapidjson/git/PKGBUILD

@@ -0,0 +1,44 @@
+# Maintainer: Martchus <martchus@gmx.net>
+
+# All my PKGBUILDs are managed at https://github.com/Martchus/PKGBUILDs where
+# you also find the URL of a binary repository.
+
+_reponame=reflective-rapidjson
+pkgname=reflective-rapidjson-git
+_name=${pkgname%-git}
+pkgver=79.b27e0ba
+pkgrel=1
+arch=('i686' 'x86_64')
+pkgdesc='Code generator for serializing/deserializing C++ objects to/from JSON using Clang and RapidJSON'
+license=('GPL')
+depends=('c++utilities-git' 'llvm-libs' 'rapidjson')
+optdepends=("boost: use Boost.Hana instead of code generator")
+optdepends=("$_name-doc: API documentation")
+makedepends=('cmake' 'clang' 'clang-tools-extra' 'boost' 'llvm' 'git')
+checkdepends=('cppunit')
+provides=("${_name}")
+conflicts=("${_name}")
+url="https://github.com/Martchus/${_reponame}"
+source=("${_reponame}::${MARTCHUS_GIT_URL_PREFIX:-git://github.com/Martchus}/${_reponame}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
+  echo "$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
+  cmake -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX="/usr"
+  make
+}
+
+check() {
+  cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
+  make check
+}
+
+package() {
+  cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
+  make DESTDIR="${pkgdir}" install
+}