From cfd95e5c4a96697d150963ecd9f3cd610fce42cb Mon Sep 17 00:00:00 2001
From: Martchus <martchus@gmx.net>
Date: Wed, 11 May 2016 22:17:53 +0200
Subject: [PATCH] Add mingw-w64-tageditor-webview

---
 tageditor/mingw-w64-webview/PKGBUILD | 58 ++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 tageditor/mingw-w64-webview/PKGBUILD

diff --git a/tageditor/mingw-w64-webview/PKGBUILD b/tageditor/mingw-w64-webview/PKGBUILD
new file mode 100644
index 00000000..8293503a
--- /dev/null
+++ b/tageditor/mingw-w64-webview/PKGBUILD
@@ -0,0 +1,58 @@
+# Maintainer: Martchus <martchus@gmx.net>
+
+# All my PKGBUILDs are managed at https://github.com/Martchus/PKGBUILDs where
+# you also find the URL of a binary repository.
+
+# set the web view provider: either webkit, webengine or none
+_webview_provider=webkit
+
+# set the JavaScript provider: either script, qml or none
+_js_provider=qml
+
+_name=tageditor
+_reponame=tageditor
+pkgname=mingw-w64-tageditor-webview
+pkgver=1.4.0
+pkgrel=1
+arch=('any')
+pkgdesc="A tag editor with Qt GUI and command-line interface supporting MP4/M4A/AAC (iTunes), ID3, Vorbis, Opus and Matroska (mingw-w64)."
+license=('GPL')
+depends=(mingw-w64-{crt,qtutilities,tagparser})
+[[ $_webview_provider == none ]] && [[ $_js_provider == none ]] && depends+=('mingw-w64-qt5-base')
+[[ $_webview_provider == webkit ]] && depends+=('mingw-w64-qt5-webkit')
+[[ $_webview_provider == webengine ]] && depends+=('mingw-w64-qt5-webengine')
+[[ $_js_provider == script ]] && depends+=('mingw-w64-qt5-script')
+[[ $_js_provider == qml ]] && depends+=('mingw-w64-qt5-declarative')
+makedepends=('mingw-w64-gcc' 'mingw-w64-cmake' 'mingw-w64-qt5-tools' 'ffmpeg')
+url="https://github.com/Martchus/${_reponame}"
+provides=('mingw-w64-tageditor')
+conflicts=('mingw-w64-tageditor')
+source=("tageditor-${pkgver}.tar.gz::https://github.com/Martchus/${_reponame}/archive/v${pkgver}.tar.gz")
+sha256sums=('37281b85c633b2f91310c0747f6ae69a108961ee5de1fa5ad3ba27a1707359aa')
+options=(!buildflags staticlibs !strip !emptydirs)
+_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
+
+build() {
+  cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame-$pkgver}"
+  # build utilities for each architecture
+  for _arch in ${_architectures}; do
+    mkdir -p build-${_arch} && pushd build-${_arch}
+    ${_arch}-cmake \
+      -DCMAKE_BUILD_TYPE=Release \
+      -DCMAKE_INSTALL_PREFIX="/usr/${_arch}" \
+      -DWEBVIEW_PROVIDER="${_webview_provider}" \
+      -DJS_PROVIDER="${_js_provider}" \
+      ../
+    make
+    popd
+  done
+}
+
+package() {
+  cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame-$pkgver}"
+  for _arch in ${_architectures}; do
+    pushd build-${_arch}
+    make DESTDIR="${pkgdir}" install-mingw-w64-strip
+    popd
+  done
+}