_name=geocoordinatecalculator
pkgname=mingw-w64-geocoordinatecalculator
pkgver=1.0.0
pkgrel=6
arch=('any')
pkgdesc="Tool for basic calculations with geo coordinates such as format conversions and calculation of distance, bearing, mid point, destination and more (mingw-w64)."
license=('GPL')
depends=('mingw-w64-crt' 'mingw-w64-c++utilities')
makedepends=('mingw-w64-gcc' 'mingw-w64-qt5-base')
url="https://github.com/Martchus/geocoordinatecalculator"
source=("geocoordinatecalculator-${pkgver}.tar.gz::https://github.com/Martchus/geocoordinatecalculator/archive/v${pkgver}.tar.gz")
_reponame=geocoordinatecalculator
sha256sums=('4e94aff9225d8873f752995c1bcc5f15')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"

# head end

build() {
    cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame-$pkgver}"
    # build for each architecture
    for _arch in ${_architectures}; do
        mkdir -p build-${_arch} && pushd build-${_arch}
        INSTALL_ROOT=$pkgdir/usr/ ${_arch}-qmake-qt5 -r ../${_name}.pro
        make
        popd
    done
}

package() {
    cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame-$pkgver}"
    for _arch in ${_architectures}; do       
        # bin stuff
        pushd build-${_arch}
        strip --strip-unneeded ./release/${_name}.exe
        install -m755 -D ./release/${_name}.exe $pkgdir/usr/${_arch}/bin/${_name}.exe
        popd  
    done
}