# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Contributor: François Charette <firmicus@gmx.net>

_pkgname=xz
pkgname=static-compat-$_pkgname
pkgver=5.2.6
pkgrel=1
pkgdesc='Library and command line tools for XZ and LZMA compressed files'
arch=('x86_64')
url='https://tukaani.org/xz/'
license=('GPL' 'LGPL' 'custom')
depends=('glibc-static-compat')
makedepends=('static-compat-configure')
options=(!emptydirs staticlibs)
source=("https://tukaani.org/${_pkgname}/${_pkgname}-${pkgver}.tar.gz"{,.sig})
sha256sums=('a2105abee17bcd2ebd15ced31b4f5eda6e17efd6b10f921a01cda4a44c91b3a0'
            'SKIP')
validpgpkeys=('3690C240CE51B4670D30AD1C38EE757D69184620')

build() {
	source static-compat-environment
	cd "${srcdir}/${_pkgname}-${pkgver}"

	static-compat-configure --disable-shared --enable-static --disable-rpath
	make
}

check() {
	source static-compat-environment
	cd "${srcdir}/${_pkgname}-${pkgver}"
	make check
}

package() {
	source static-compat-environment
	cd "${srcdir}/${_pkgname}-${pkgver}"
	make DESTDIR="${pkgdir}" install
	install -d -m755 "${pkgdir}/usr/share/licenses/${pkgname}/"
	ln -sf /usr/static/share/doc/xz/COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
	rm -r "$pkgdir/$static_compat_prefix"/bin
	rm -r "$pkgdir/$static_compat_prefix"/share/{man,doc,locale}
}