57 lines
1.9 KiB
Bash
57 lines
1.9 KiB
Bash
# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
|
|
# Contributor: Jan de Groot <jgc@archlinux.org>
|
|
|
|
_pkgname=freetype2
|
|
pkgname=$_pkgname-static
|
|
pkgver=2.10.4
|
|
pkgrel=1
|
|
pkgdesc="Font rasterization library"
|
|
url="https://www.freetype.org/"
|
|
arch=(x86_64)
|
|
license=(GPL)
|
|
# adding harfbuzz for improved OpenType features auto-hinting
|
|
# introduces a cycle dep to harfbuzz depending on freetype wanted by upstream
|
|
depends=(zlib bzip2-static libpng-static harfbuzz-static)
|
|
makedepends=(libx11-static)
|
|
options=(staticlibs)
|
|
source=(https://download-mirror.savannah.gnu.org/releases/freetype/freetype-$pkgver.tar.xz{,.sig}
|
|
0001-Enable-table-validation-modules.patch
|
|
0002-Enable-subpixel-rendering.patch
|
|
0003-Enable-infinality-subpixel-hinting.patch
|
|
0004-Enable-long-PCF-family-names.patch)
|
|
sha256sums=('86a854d8905b19698bbc8f23b860bc104246ce4854dcea8e3b0fb21284f75784'
|
|
'SKIP'
|
|
'f41df4f336d5e82e58733c7a4594476c9216cfc85c096327745a7e1b559e17e1'
|
|
'dc77c1cfee4bf8e7e0690628c95d211df09e0d0750e4c8f075b78b5f105514f7'
|
|
'21a62bc12b848320c686d602d8d4e3bcd51294a9def4dc9c301736e077b59f3f'
|
|
'266384222f87a02fb02b2179828f6c26fe6d7b1fd09d1f7e3734e7fcb09cda2e')
|
|
validpgpkeys=(58E0C111E39F5408C5D3EC76C1A60EACE707FDA5) # Werner Lemberg <wl@gnu.org>
|
|
|
|
prepare() {
|
|
cd freetype-$pkgver
|
|
patch -Np1 -i ../0001-Enable-table-validation-modules.patch
|
|
patch -Np1 -i ../0002-Enable-subpixel-rendering.patch
|
|
patch -Np1 -i ../0003-Enable-infinality-subpixel-hinting.patch
|
|
patch -Np1 -i ../0004-Enable-long-PCF-family-names.patch
|
|
}
|
|
|
|
build() {
|
|
cd freetype-$pkgver
|
|
export PKG_CONFIG_PATH=/usr/static/lib/pkgconfig:/usr/lib/pkgconfig
|
|
./configure --prefix=/usr/static --disable-shared --enable-static
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd freetype-$pkgver
|
|
make -k check
|
|
}
|
|
|
|
package() {
|
|
cd freetype-$pkgver
|
|
make DESTDIR="$pkgdir" install
|
|
rm -rf "${pkgdir}"/usr/static/share/
|
|
}
|
|
|
|
# vim:set ts=2 sw=2 et:
|