51 lines
1.5 KiB
Bash
51 lines
1.5 KiB
Bash
# Maintainer: Martchus <martchus@gmx.net>
|
|
|
|
# All my PKGBUILDs are managed at https://github.com/Martchus/PKGBUILDs where
|
|
# you also find the URL of a binary repository.
|
|
|
|
_reponame=qtutilities
|
|
pkgname=qtutilities-git
|
|
_name=${pkgname%-git}
|
|
pkgver=421.b5af7fe
|
|
pkgrel=2
|
|
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
|
|
pkgdesc='Common Qt related C++ classes and routines used by my applications such as dialogs, widgets and models'
|
|
license=('GPL')
|
|
depends=('libc++utilities-git.so' 'qt5-base' 'mesa')
|
|
optdepends=("$_name-doc: API documentation")
|
|
makedepends=('cmake' 'git' 'ninja' 'qt5-tools')
|
|
provides=(libqtutilities-git.so)
|
|
url="https://github.com/Martchus/${_reponame}"
|
|
source=("${_reponame}::${MARTCHUS_GIT_URL_PREFIX:-git+https://github.com/Martchus}/${_reponame}.git")
|
|
sha256sums=('SKIP')
|
|
|
|
pkgver() {
|
|
cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
|
|
echo "$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
|
|
}
|
|
|
|
build() {
|
|
cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
|
|
cmake \
|
|
-G Ninja \
|
|
-DCMAKE_BUILD_TYPE:STRING='Release' \
|
|
-DCMAKE_INSTALL_PREFIX:PATH='/usr' \
|
|
-DCONFIGURATION_NAME:STRING='git' \
|
|
-DCONFIGURATION_PACKAGE_SUFFIX:STRING='-git' \
|
|
-DCONFIGURATION_TARGET_SUFFIX:STRING='git' \
|
|
-DBUILD_SHARED_LIBS:BOOL=ON \
|
|
-DBUILTIN_TRANSLATIONS:BOOL=ON \
|
|
.
|
|
ninja
|
|
}
|
|
|
|
check() {
|
|
cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
|
|
QT_QPA_PLATFORM=offscreen ninja check
|
|
}
|
|
|
|
package() {
|
|
cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
|
|
DESTDIR="${pkgdir}" ninja install
|
|
}
|