63 lines
2.3 KiB
Bash
63 lines
2.3 KiB
Bash
# $Id$
|
|
# Contributor: Martchus <martchus@gmx.net>
|
|
# Contributor: Evangelos Foutras <evangelos@foutrelis.com>
|
|
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
|
|
# Contributor: Sebastien Piccand <sebcactus gmail com>
|
|
|
|
pkgname=('handbrake-libfdk_aac' 'handbrake-cli-libfdk_aac')
|
|
_name=${pkgname%-libfdk_aac}
|
|
pkgver=1.1.1
|
|
pkgrel=1
|
|
arch=('i686' 'x86_64')
|
|
url="https://handbrake.fr/"
|
|
license=('GPL')
|
|
makedepends=('intltool' 'python2' 'yasm' 'wget' 'cmake' 'bzip2' 'gcc-libs'
|
|
'zlib' 'libnotify' 'gst-plugins-base' 'gtk3' 'dbus-glib' 'libass'
|
|
'lame' 'libxml2' 'opus' 'libvorbis' 'libtheora' 'libsamplerate'
|
|
'x264' 'jansson' 'librsvg' 'libgudev'
|
|
'libfdk-aac')
|
|
source=(https://download.handbrake.fr/releases/$pkgver/HandBrake-$pkgver-source.tar.bz2
|
|
https://github.com/HandBrake/HandBrake/releases/download/$pkgver/HandBrake-$pkgver-source.tar.bz2.sig)
|
|
sha256sums=('e3390c5fd901fb06d72e29c62a63d373d5fb5b3467295d114d815ae7b78a9d7a'
|
|
'SKIP')
|
|
validpgpkeys+=('1629C061B3DDE7EB4AE34B81021DB8B44E4A8645') # HandBrake Team <developers@handbrake.fr>
|
|
|
|
build() {
|
|
cd "$srcdir/HandBrake-$pkgver"
|
|
|
|
./configure --prefix=/usr --enable-fdk
|
|
make -C build
|
|
}
|
|
|
|
package_handbrake-libfdk_aac() {
|
|
pkgdesc="Multithreaded video transcoder"
|
|
depends=('bzip2' 'gcc-libs' 'zlib' 'gst-plugins-base' 'libnotify' 'dbus-glib'
|
|
'gtk3' 'libass' 'lame' 'libxml2' 'opus' 'libvorbis' 'libtheora'
|
|
'libsamplerate' 'libx264' 'jansson' 'librsvg' 'libgudev'
|
|
'desktop-file-utils' 'hicolor-icon-theme' 'libfdk-aac')
|
|
optdepends=('gst-plugins-good: for video previews'
|
|
'gst-libav: for video previews'
|
|
'libdvdcss: for decoding encrypted DVDs')
|
|
provides=("${_name}")
|
|
conflicts=("${_name}")
|
|
|
|
cd "$srcdir/HandBrake-$pkgver/build"
|
|
|
|
make DESTDIR="$pkgdir" install
|
|
rm "$pkgdir/usr/bin/HandBrakeCLI"
|
|
}
|
|
|
|
package_handbrake-cli-libfdk_aac() {
|
|
pkgdesc="Multithreaded video transcoder (CLI)"
|
|
depends=('bzip2' 'gcc-libs' 'zlib' 'libass' 'lame' 'libxml2' 'opus'
|
|
'libvorbis' 'libtheora' 'libsamplerate' 'libx264' 'jansson')
|
|
optdepends=('libdvdcss: for decoding encrypted DVDs')
|
|
provides=("${_name}-cli")
|
|
conflicts=("${_name}-cli")
|
|
|
|
cd "$srcdir/HandBrake-$pkgver/build"
|
|
install -D HandBrakeCLI "$pkgdir/usr/bin/HandBrakeCLI"
|
|
}
|
|
|
|
# vim:set ts=2 sw=2 et:
|