# meta data
projectname = repoindex
appname = "Repository Index"
appauthor = Martchus
appurl = "https://github.com/$${appauthor}/$${projectname}"
QMAKE_TARGET_DESCRIPTION = "Provides a web interface to browse Arch Linux package repositories."
VERSION = 0.0.2

# include ../../common.pri when building as part of a subdirs project; otherwise include general.pri
!include(../../common.pri) {
    !include(./general.pri) {
        error("Couldn't find the common.pri or the general.pri file!")
    }
}

# basic configuration: console application
TEMPLATE = app
CONFIG += console # enables qDebug()
QT += core network websockets concurrent KArchive

# add defines for configuration
CONFIG(release, debug|release) {
    DEFINES += NDEBUG
}

# add project files
HEADERS += \
    alpm/manager.h \
    alpm/package.h \
    alpm/list.h \
    alpm/utilities.h \
    network/server.h \
    network/connection.h \
    alpm/group.h \
    alpm/config.h \
    alpm/resolvebuildorder.h \
    alpm/mingwbundle.h \
    network/userrepository.h \
    alpm/alpmpackage.h \
    alpm/aurpackage.h \
    alpm/alpmdatabase.h \
    alpm/repository.h \
    alpm/upgradelookup.h \
    alpm/suggestionslookup.h \
    alpm/packageinfolookup.h \
    alpm/packagelookup.h \
    alpm/packagefinder.h

SOURCES += \
    main.cpp \
    alpm/manager.cpp \
    alpm/package.cpp \
    alpm/utilities.cpp \
    network/server.cpp \
    network/connection.cpp \
    alpm/group.cpp \
    alpm/config.cpp \
    alpm/resolvebuildorder.cpp \
    alpm/mingwbundle.cpp \
    network/userrepository.cpp \
    alpm/alpmpackage.cpp \
    alpm/aurpackage.cpp \
    alpm/alpmdatabase.cpp \
    alpm/repository.cpp \
    alpm/upgradelookup.cpp \
    alpm/suggestionslookup.cpp \
    alpm/packageinfolookup.cpp \
    alpm/packagelookup.cpp \
    alpm/packagefinder.cpp

OTHER_FILES += \
    README.md \
    LICENSE \
    CMakeLists.txt \
    resources/config.h.in \
    resources/windows.rc.in \
    resources/systemd/repoindex.service \
    resources/settings/repoindex.conf.js

DISTFILES += \
    web/index.html \
    web/js/pagination.js \
    web/js/entrymanagement.js \
    web/js/packagemanagement.js \
    web/js/groupmanagement.js \
    web/js/pagemanagement.js \
    web/js/repomanagement.js \
    web/js/proto.js \
    web/js/utils.js \
    web/css/core.css \
    web/css/dashboard.css \
    web/js/client.js \
    web/3rdparty/bootstrap/css/bootstrap.min.css \
    web/3rdparty/bootstrap_dropdowns_enhancement/css/dropdowns-enhancement.min.css \
    web/3rdparty/bootstrap/js/bootstrap.min.js \
    web/3rdparty/bootstrap_dropdowns_enhancement/js/dropdowns-enhancement.js


# libs and includepath
CONFIG(debug, debug|release) {
    LIBS += -lc++utilitiesd
} else {
    LIBS += -lc++utilities
}
LIBS += -lalpm

# installs
target.path = $$(INSTALL_ROOT)/bin
INSTALLS += target