_pkgbase=boost
pkgname=boost-doc
pkgver=1.79.0
_srcname=boost_${pkgver//./_}
pkgrel=1
pkgdesc='Free peer-reviewed portable C++ source libraries (HTML documentation)'
url='https://www.boost.org/'
arch=('x86_64')
license=('custom')
makedepends=()
source=(https://boostorg.jfrog.io/artifactory/main/release/$pkgver/source/$_srcname.tar.gz)
sha256sums=('273f1be93238a068aba4f9735a4a2b003019af067b9c183ed227780b8f36062c')
options=(!strip)

package() {
   cd ${_srcname}
   local dest=$pkgdir/usr/share/$_pkgbase/doc

   install -dm755 "$dest"
   find \( \
      -iname '*.htm' -o -iname '*.html' -o -iname '*.css' -o \
      -iname '*.png' -o -iname '*.gif' -o -iname '*.jpg' -o -iname '*.js' \
   \) -exec cp --target-directory="$dest" --parents --verbose {} +
}

# vim: ts=2 sw=2 et:
