PKGBUILDs/pocketsphinx/default/PKGBUILD

# Maintainer: Marco Pompili <aur AT emarcs DOT org>
# Contributor: Ben Duffield <bavardage AT archlinux.us>
# Contributor: Martchus <martchus@gmx.net>

pkgname=pocketsphinx
pkgver=5prealpha
pkgrel=5
pkgdesc='Lightweight speech recognition engine'
arch=('i686' 'x86_64')
url='http://cmusphinx.sourceforge.net'
license=('BSD')
makedepends=('swig' 'python2' 'python')
depends=('sphinxbase=5prealpha' 'gstreamer0.10-base' 'gst-plugins-base-libs')
source=("http://downloads.sourceforge.net/cmusphinx/$pkgname-$pkgver.tar.gz"
        "https://raw.githubusercontent.com/cmusphinx/pocketsphinx/master/LICENSE")
sha256sums=('ad9f5f5c5ce79ff87b63d527f8f4d3e2f54c0c1da53793895991a8849ca47701'
            '49181202f2b991d25f6cac8cd1705994494b9600d4311794ecbb9fcf8b188aef')
options=('!libtool')

prepare() {
  cd "$pkgname-$pkgver"

  msg2 "Reconfiguring project for current version of Automake"
  autoreconf -ivf > /dev/null

  cd ..
  cp -R "$pkgname-$pkgver" "$pkgname-$pkgver-py2"
  cp -R "$pkgname-$pkgver" "$pkgname-$pkgver-py3"
}

build() {
  msg2 "Building python3 environment"
  export PYTHON=/usr/bin/python
  cd "$pkgname-$pkgver-py3"
  ./configure --prefix=/usr
  make

  msg2 "Building python2 environment"
  cd "../$pkgname-$pkgver-py2"
  export PYTHON=/usr/bin/python2
  ./configure --prefix=/usr
  make
}

package() {
  cd "$pkgname-$pkgver-py3"

  make DESTDIR="$pkgdir" install

  cd "../$pkgname-$pkgver-py2/swig"
  make DESTDIR="$pkgdir" install

  install -d -m755 "$pkgdir/usr/share/licenses/$pkgname"
  install -D -m644 "${srcdir}/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

  libtool --finish "$pkgdir/usr/lib"
  libtool --finish "$pkgdir/usr/lib/gstreamer-1.0"
  libtool --finish "$pkgdir/usr/lib/python2.7/site-packages/pocketsphinx"
  libtool --finish "$pkgdir/usr/lib/python3.5/site-packages/pocketsphinx"
}