Import libdvdread from official repos and update to 6.0.1

The latest version is required to build vlc-nightly package.

libdvdread/default/PKGBUILD

@@ -0,0 +1,40 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc@archlinux.org>
+# Contributor: Thomas Baechler <thomas@archlinux.org>
+# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
+# Contributor: Martchus <martchus@gmx.net>
+
+pkgname=libdvdread
+pkgver=6.0.1
+pkgrel=1
+pkgdesc="Provides a simple foundation for reading DVD video disks"
+arch=(x86_64)
+url="https://www.videolan.org/developers/libdvdnav.html"
+license=('GPL')
+depends=('glibc')
+makedepends=('libdvdcss' 'git')
+optdepends=('libdvdcss: for decoding encrypted DVDs')
+_commit=b851de7220657aaba96d447abd2937ffd2a23490  # tags/6.0.1^0
+source=("git+https://code.videolan.org/videolan/libdvdread.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed -e 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  autoreconf -fi
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="${pkgdir}" install
+}