Import handbrake with libfdk-aac enabled

handbrake/libfdk_aac/PKGBUILD

@@ -0,0 +1,58 @@
+# $Id$
+# Contributor: Martchus <martchus@gmx.net>
+# Contributor: Evangelos Foutras <evangelos@foutrelis.com>
+# Contributor: Giovanni Scafora <giovanni@archlinux.org>
+# Contributor: Sebastien Piccand <sebcactus gmail com>
+
+pkgname=('handbrake-libfdk_aac' 'handbrake-cli-libfdk_aac')
+_name=${pkgname%-libfdk_aac}
+pkgver=1.0.7
+pkgrel=1
+arch=('i686' 'x86_64')
+url="https://handbrake.fr/"
+license=('GPL')
+makedepends=('intltool' 'python2' 'yasm' 'wget' 'cmake' 'bzip2' 'gcc-libs'
+             'zlib' 'libnotify' 'gst-plugins-base' 'gtk3' 'dbus-glib' 'libass'
+             'lame' 'libxml2' 'opus' 'libvorbis' 'libtheora' 'libsamplerate'
+             'x264' 'libx264' 'jansson' 'librsvg' 'libgudev')
+source=(https://handbrake.fr/mirror/HandBrake-$pkgver.tar.bz2)
+sha256sums=('ffdee112f0288f0146b965107956cd718408406b75db71c44d2188f5296e677f')
+
+build() {
+  cd "$srcdir/HandBrake-$pkgver"
+
+  ./configure --prefix=/usr --enable-fdk
+  make -C build
+}
+
+package_handbrake-libfdk_aac() {
+  pkgdesc="Multithreaded video transcoder"
+  depends=('bzip2' 'gcc-libs' 'zlib' 'gst-plugins-base' 'libnotify' 'dbus-glib'
+           'gtk3' 'libass' 'lame' 'libxml2' 'opus' 'libvorbis' 'libtheora'
+           'libsamplerate' 'libx264' 'jansson' 'librsvg' 'libgudev'
+           'desktop-file-utils' 'hicolor-icon-theme' 'libfdk-aac')
+  optdepends=('gst-plugins-good: for video previews'
+              'gst-libav: for video previews'
+              'libdvdcss: for decoding encrypted DVDs')
+  provides=("${_name}")
+  conflicts=("${_name}")
+
+  cd "$srcdir/HandBrake-$pkgver/build"
+
+  make DESTDIR="$pkgdir" install
+  rm "$pkgdir/usr/bin/HandBrakeCLI"
+}
+
+package_handbrake-cli-libfdk_aac() {
+  pkgdesc="Multithreaded video transcoder (CLI)"
+  depends=('bzip2' 'gcc-libs' 'zlib' 'libass' 'lame' 'libxml2' 'opus'
+           'libvorbis' 'libtheora' 'libsamplerate' 'libx264' 'jansson')
+  optdepends=('libdvdcss: for decoding encrypted DVDs')
+  provides=("${_name}-cli")
+  conflicts=("${_name}-cli")
+
+  cd "$srcdir/HandBrake-$pkgver/build"
+  install -D HandBrakeCLI "$pkgdir/usr/bin/HandBrakeCLI"
+}
+
+# vim:set ts=2 sw=2 et: