# Maintainer: Martchus <martchus@gmx.net>

# DOES NOT WORK YET (mingw-64 currently not supported by Qt WebEngine)

# All my PKGBUILDs are managed at https://github.com/Martchus/PKGBUILDs where
# you also find the URL of a binary repository.

_qt_module=qtwebengine
pkgname=mingw-w64-qt5-webengine-git
pkgver=5.6.0
pkgrel=1
arch=('any')
pkgdesc='Provides support for web applications using the Chromium browser project (mingw-w64, git version)'
depends=('mingw-w64-qt5-webchannel' 'mingw-w64-qt5-location')
makedepends=('mingw-w64-gcc' 'git' 'python2' 'gperf' 'ruby' 'mingw-w64-pkg-config')
provides=(${pkgname%-git})
conflicts=(${pkgname%-git})
options=('!strip' '!buildflags' 'staticlibs')
license=('custom' 'FDL' 'GPL3' 'LGPL')
url="https://www.qt.io/"
_pkgfqn="${_qt_module}-opensource-src-${pkgver}"
groups=(mingw-w64-qt mingw-w64-qt5)
source=(${_qt_module}::git://code.qt.io/qt/${_qt_module}.git#branch=dev)
md5sums=('SKIP')

_architectures="i686-w64-mingw32 x86_64-w64-mingw32"

pkgver() {
  cd "${srcdir}/${_qt_module}"
  echo "$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

prepare() {
  cd "${srcdir}/${_qt_module}"

  # use python2 for Python 2.x
  find . -name '*.py' -exec sed -i \
    's|#![ ]*/usr/bin/python$|&2|;s|#![ ]*/usr/bin/env python$|&2|' {} +

  # in qtwebengine there are still a lot of relative calls which need a workaround
  mkdir "${srcdir}"/python2-path
  ln -s /usr/bin/python2 "${srcdir}"/python2-path/python
}

build() {
  unset PKG_CONFIG_PATH
  # python2 workaround
  export PATH="${srcdir}/python2-path:$PATH"
  cd "${srcdir}/${_qt_module}"
  for _arch in ${_architectures}; do
    mkdir -p build-${_arch} && pushd build-${_arch}
    ${_arch}-qmake-qt5 ../${_qt_module}.pro
    make
    popd
  done
}

package() {
  for _arch in ${_architectures}; do
    cd "${srcdir}/${_qt_module}/build-${_arch}"
    make INSTALL_ROOT="${pkgdir}" install

    # The .dll's are installed in both bindir and libdir
    # One copy of the .dll's is sufficient
    rm -f "${pkgdir}/usr/${_arch}/lib/"*.dll
    find "${pkgdir}/usr/${_arch}" -name "*.exe" -o -name "*.bat" -o -name "*.def" -o -name "*.exp" -o -name '*.prl' | xargs -rtl1 rm
    find "${pkgdir}/usr/${_arch}" -name "*.dll" -exec ${_arch}-strip --strip-unneeded {} \;
    find "${pkgdir}/usr/${_arch}" -name "*.a" -o -name "*.dll" | xargs -rtl1 ${_arch}-strip -g
  done
}