# Contributor: David Runge <dvzrv@archlinux.org>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Simone Sclavi 'Ito' <darkhado@gmail.com>

_pkgname=libjpeg-turbo
pkgname=static-compat-$_pkgname
pkgver=2.1.4
pkgrel=1
pkgdesc="JPEG image codec with accelerated baseline compression and decompression"
arch=(x86_64)
url="https://libjpeg-turbo.org/"
license=(BSD)
depends=(glibc-static-compat)
makedepends=(static-compat-cmake nasm)
options=(staticlibs)
source=(https://sourceforge.net/projects/$_pkgname/files/$pkgver/$_pkgname-$pkgver.tar.gz{,.sig})
sha512sums=('511f065767c022da06b6c36299686fa44f83441646f7e33b766c6cfab03f91b0e6bfa456962184071dadaed4057ba9a29cba685383f3eb86a4370a1a53731a70'
            'SKIP')
b2sums=('80ffd77d58a37eae0bdc1868d994f34ea52c13e2624c720b1d0b6ec4d6d14b16911163ccd4009c8d6eda214f31e1fff78bb7eb4739ae6589d0fd8c7008c0e972'
        'SKIP')
validpgpkeys=('0338C8D8D9FDA62CF9C421BD7EC2DBB6F4DBF434') # The libjpeg-turbo Project (Signing key for official binaries) <information@libjpeg-turbo.org>

build() {
  source static-compat-environment
  static-compat-cmake -DCMAKE_INSTALL_LIBDIR="$static_compat_prefix"/lib \
        -DWITH_JAVA=OFF\
        -DWITH_JPEG8=ON \
        -W no-dev \
        -B build \
        -S $_pkgname-$pkgver
  make VERBOSE=1 -C build
}

check() {
  source static-compat-environment
  make test -C build
}

package() {
  source static-compat-environment
  make VERBOSE=1 DESTDIR="$pkgdir" docdir="$static_compat_prefix"/share/doc/$_pkgname exampledir="$static_compat_prefix"/share/doc/$_pkgname install -C build

  install -d "$pkgdir/usr/share/licenses/$pkgname"
  ln -s ../../doc/$_pkgname/LICENSE.md "$pkgdir/usr/share/licenses/$pkgname"
  # header required by some dependants
  # https://bugs.archlinux.org/task/24787
  install -vDm 644 $_pkgname-$pkgver/jpegint.h "$pkgdir/$static_compat_prefix/include"
  rm -r "$pkgdir/$static_compat_prefix"/share
  find "$pkgdir/$static_compat_prefix"/lib -iname '*.so*' -delete
}