65 lines
2.4 KiB
Bash
65 lines
2.4 KiB
Bash
# $Id$
|
|
# Contributor: Martchus <martchus@gmx.net>
|
|
# Contributor: Evangelos Foutras <evangelos@foutrelis.com>
|
|
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
|
|
# Contributor: Sebastien Piccand <sebcactus gmail com>
|
|
|
|
pkgname=('handbrake-libfdk_aac' 'handbrake-cli-libfdk_aac')
|
|
_name=${pkgname%-libfdk_aac}
|
|
pkgver=1.2.2
|
|
pkgrel=1
|
|
arch=('i686' 'x86_64')
|
|
url="https://handbrake.fr/"
|
|
license=('GPL')
|
|
makedepends=('intltool' 'python2' 'nasm' 'wget' 'cmake' 'bzip2' 'gcc-libs' 'xz'
|
|
'zlib' 'libnotify' 'gst-plugins-base' 'gtk3' 'dbus-glib' 'libass'
|
|
'lame' 'libxml2' 'opus' 'libvorbis' 'libtheora' 'libsamplerate'
|
|
'speex' 'x264' 'jansson' 'librsvg' 'libgudev'
|
|
'libfdk-aac')
|
|
source=(https://download.handbrake.fr/releases/$pkgver/HandBrake-$pkgver-source.tar.bz2
|
|
https://github.com/HandBrake/HandBrake/releases/download/$pkgver/HandBrake-$pkgver-source.tar.bz2.sig)
|
|
sha256sums=('df6816f517d60ae8a6626aa731821af2d1966c155fa53b2b9a06c47f3c565e4c'
|
|
'SKIP')
|
|
validpgpkeys+=('1629C061B3DDE7EB4AE34B81021DB8B44E4A8645') # HandBrake Team <developers@handbrake.fr>
|
|
|
|
build() {
|
|
cd "$srcdir/HandBrake-$pkgver"
|
|
|
|
./configure --prefix=/usr --disable-gtk-update-checks --enable-fdk
|
|
make -C build
|
|
}
|
|
|
|
package_handbrake-libfdk_aac() {
|
|
pkgdesc="Multithreaded video transcoder"
|
|
depends=('bzip2' 'gcc-libs' 'zlib' 'gst-plugins-base' 'libnotify' 'dbus-glib'
|
|
'gtk3' 'xz' 'libass' 'lame' 'libxml2' 'opus' 'libvorbis' 'libtheora'
|
|
'libsamplerate' 'speex' 'x264' 'jansson' 'librsvg' 'libgudev'
|
|
'desktop-file-utils' 'hicolor-icon-theme'
|
|
'libfdk-aac')
|
|
optdepends=('gst-plugins-good: for video previews'
|
|
'gst-libav: for video previews'
|
|
'libdvdcss: for decoding encrypted DVDs')
|
|
provides=("${_name}")
|
|
conflicts=("${_name}")
|
|
|
|
cd "$srcdir/HandBrake-$pkgver/build"
|
|
|
|
make DESTDIR="$pkgdir" install
|
|
rm "$pkgdir/usr/bin/HandBrakeCLI"
|
|
}
|
|
|
|
package_handbrake-cli-libfdk_aac() {
|
|
pkgdesc="Multithreaded video transcoder (CLI)"
|
|
depends=('bzip2' 'gcc-libs' 'zlib' 'xz' 'libass' 'lame' 'libxml2' 'opus'
|
|
'libvorbis' 'libtheora' 'libsamplerate' 'speex' 'x264' 'jansson'
|
|
'libfdk-aac')
|
|
optdepends=('libdvdcss: for decoding encrypted DVDs')
|
|
provides=("${_name}-cli")
|
|
conflicts=("${_name}-cli")
|
|
|
|
cd "$srcdir/HandBrake-$pkgver/build"
|
|
install -D HandBrakeCLI "$pkgdir/usr/bin/HandBrakeCLI"
|
|
}
|
|
|
|
# vim:set ts=2 sw=2 et:
|