36 lines
1.1 KiB
Bash
36 lines
1.1 KiB
Bash
# Maintainer: Martchus <martchus@gmx.net>
|
|
|
|
# All my PKGBUILDs are managed at https://github.com/Martchus/PKGBUILDs where
|
|
# you also find the URL of a binary repository.
|
|
|
|
pkgname=qt6-wayland
|
|
_qtver=6.0.0
|
|
pkgver=${_qtver/-/}
|
|
pkgrel=1
|
|
arch=(x86_64)
|
|
url='https://www.qt.io'
|
|
license=(GPL3 LGPL3 FDL custom)
|
|
pkgdesc='Provides APIs for Wayland'
|
|
depends=(qt6-declarative libxcomposite)
|
|
makedepends=(cmake vulkan-headers ninja)
|
|
groups=(qt6)
|
|
_pkgfqn="${pkgname/6-/}-everywhere-src-${_qtver}"
|
|
source=("https://download.qt.io/official_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz")
|
|
sha256sums=('a54d6530588998f2e011fc873f5744f0ab194f2286241f4aa8d7a7bc2967576f')
|
|
|
|
build() {
|
|
cmake -G Ninja -B build -S $_pkgfqn
|
|
cmake --build build
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="$pkgdir" cmake --install build
|
|
|
|
# Drop QMAKE_PRL_BUILD_DIR because reference the build dir
|
|
find "$pkgdir/usr/lib" -type f -name '*.prl' \
|
|
-exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;
|
|
|
|
install -d "$pkgdir"/usr/share/licenses
|
|
ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/qt6-wayland
|
|
}
|