pkgname=mingw-w64-clang-aarch64-abseil-cpp
pkgver=20250127.1
pkgrel=1
pkgdesc='Collection of C++ library code designed to augment the C++ standard library (mingw-w64-clang-aarch64)'
arch=('any')
url='https://abseil.io'
license=('Apache')
depends=('mingw-w64-clang-aarch64-crt' 'mingw-w64-clang-aarch64-winpthreads')
makedepends=('mingw-w64-clang-aarch64-cmake-static')
options=('!buildflags' '!strip' 'staticlibs')
source=("https://github.com/abseil/abseil-cpp/archive/$pkgver/abseil-cpp-$pkgver.tar.gz")
sha256sums=('b396401fd29e2e679cace77867481d388c807671dc2acc602a0259eeb79b7811')

_architectures="aarch64-w64-mingw32"

build() {
  cd abseil-cpp-$pkgver
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    ${_arch}-cmake -B build-${_arch} .
    cmake --build build-${_arch}
    ${_arch}-cmake-static -B build-static-${_arch} -DCMAKE_INSTALL_PREFIX:PATH=/usr/$_arch/static \ .
    cmake --build build-static-${_arch}
  done
}

package() {
  cd abseil-cpp-$pkgver
  for _arch in $_architectures; do
    DESTDIR=$pkgdir cmake --install build-${_arch}
    DESTDIR=$pkgdir cmake --install build-static-${_arch}
    $STRIP --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
    $STRIP -g "$pkgdir"/usr/${_arch}/lib/*.a "$pkgdir"/usr/${_arch}/static/lib/*.a
  done
}
