# Maintainer: drakkan <nicola.murino at gmail dot com>
pkgname=mingw-w64-clang-aarch64-libffi
pkgver=3.4.6
pkgrel=1
pkgdesc="Portable foreign function interface library (mingw-w64-clang-aarch64)"
arch=(any)
depends=(mingw-w64-clang-aarch64-crt)
makedepends=(mingw-w64-clang-aarch64-configure)
options=(staticlibs !buildflags !strip)
license=(MIT)
url="http://sourceware.org/libffi"
source=(https://github.com/libffi/libffi/releases/download/v$pkgver/libffi-$pkgver.tar.gz)
sha256sums=('b0dea9df23c863a7a50e825440f3ebffabd65df1497108e5d437747843895a4e')

_architectures="aarch64-w64-mingw32"

prepare() {
  cd "${srcdir}/libffi-${pkgver}"
  if [[ $pkgname =~ .*-clang-.* ]]; then
    sed -i -e '2iac_cv_c_bigendian=no' configure
  fi
}

build() {
  export USE_COMPILER_WRAPPERS=1
  cd "${srcdir}/libffi-${pkgver}"
  unset LDFLAGS
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    mkdir -p build-${_arch} && pushd build-${_arch}
    local extra_args
    [[ $pkgname =~ .*-clang-.* ]] && extra_args+=--disable-symvers
    ${_arch}-configure \
      --target=${_arch} \
      --enable-pax_emutramp \
      $extra_args
    make
    popd
  done
}

package() {
  export USE_COMPILER_WRAPPERS=1
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    cd "${srcdir}/libffi-${pkgver}/build-${_arch}"
    make DESTDIR="${pkgdir}" install
    rm "$pkgdir/usr/${_arch}/share/info/dir"
    find "$pkgdir/usr/${_arch}" -name '*.exe' -exec $STRIP {} \;
    find "$pkgdir/usr/${_arch}" -name '*.dll' -exec $STRIP --strip-unneeded {} \;
    find "$pkgdir/usr/${_arch}" -name '*.a' -o -name '*.dll' | xargs $STRIP -g
  done
}

# vim:set ts=2 sw=2 et:
