# Maintainer: drakkan <nicola.murino at gmail dot com>
pkgname=mingw-w64-clang-aarch64-libidn2
pkgver=2.3.7
pkgrel=1
pkgdesc="A free software implementation of IDNA2008 (mingw-w64-clang-aarch64)"
arch=(any)
url="http://www.gnu.org/software/libidn"
license=("GPL3, LGPL3")
makedepends=(mingw-w64-clang-aarch64-configure)
depends=(mingw-w64-clang-aarch64-crt mingw-w64-clang-aarch64-libunistring)
options=(staticlibs !strip !buildflags)
source=("https://ftp.gnu.org/pub/gnu/libidn/libidn2-${pkgver}.tar.gz")
sha256sums=('4c21a791b610b9519b9d0e12b8097bf2f359b12f8dd92647611a929e6bfd7d64')

_architectures="aarch64-w64-mingw32"

build() {
  export USE_COMPILER_WRAPPERS=1
  cd "${srcdir}/libidn2-${pkgver}"
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    mkdir -p build-${_arch} && pushd build-${_arch}
    ${_arch}-configure --disable-nls --disable-doc
    make
    popd
  done
}

package() {
  export USE_COMPILER_WRAPPERS=1
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    cd "${srcdir}/libidn2-${pkgver}/build-${_arch}"
    make DESTDIR="$pkgdir" install
    rm "$pkgdir"/usr/${_arch}/bin/*.exe
    $STRIP --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
    $STRIP -g "$pkgdir"/usr/${_arch}/lib/*.a
  done
}

# vim: ts=2 sw=2 et:
