# Maintainer: pingplug < aur at pingplug dot me >
# Contributor: Schala Zeal < schalaalexiazeal at gmail dot com >
# Contributor: Filip Brcic < brcha at gna dot org >

_commit=fa05c11a0047f2927e76d08f9fcf6638ded7ff50  # tags/dbus-1.14.10^0
_architectures="aarch64-w64-mingw32"

pkgname=mingw-w64-clang-aarch64-dbus
pkgver=1.14.10
pkgrel=1
pkgdesc="Freedesktop.org message bus system (mingw-w64-clang-aarch64)"
arch=('any')
url="https://wiki.freedesktop.org/www/Software/dbus/"
license=('custom' 'GPL')
depends=('mingw-w64-clang-aarch64-expat')
makedepends=('mingw-w64-clang-aarch64-configure'
             'docbook-xsl'
             'autoconf-archive'
             'git')
provides=('mingw-w64-clang-aarch64-libdbus')
options=('!strip' 'staticlibs' '!buildflags')
source=("git+https://gitlab.freedesktop.org/dbus/dbus.git#commit=${_commit}")
sha256sums=('SKIP')

pkgver() {
  cd "${srcdir}/dbus"
  git describe --tags | sed 's/^dbus-//;s/-/+/g'
}

prepare() {
  cd "${srcdir}/dbus"
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  export USE_COMPILER_WRAPPERS=1
  cd "${srcdir}/dbus"
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    mkdir -p build-${_arch} && pushd build-${_arch}
    ${_arch}-configure \
      --target=${_arch} \
      --with-xml=expat \
      --disable-systemd \
      --disable-tests \
      --disable-Werror \
      --disable-asserts \
      --disable-verbose-mode \
      --disable-xml-docs \
      --disable-doxygen-docs \
      --disable-ducktype-docs
    make
    popd
  done
}

package() {
  export USE_COMPILER_WRAPPERS=1
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    cd "${srcdir}/dbus/build-${_arch}"
    make DESTDIR="${pkgdir}" install
    find "${pkgdir}/usr/${_arch}" -name "*.exe" -exec $STRIP {} \;
    find "${pkgdir}/usr/${_arch}" -name "*.dll" -exec $STRIP --strip-unneeded {} \;
    find "${pkgdir}/usr/${_arch}" -name "*.a" -o -name "*.dll" | xargs $STRIP -g
  done
}

# vim:set ts=2 sw=2 et:
