pkgname=mingw-w64-clang-aarch64-libpng
pkgver=1.6.44
_apngver=$pkgver
pkgrel=1
arch=('any')
pkgdesc="A collection of routines used to create PNG format graphics (mingw-w64-clang-aarch64)"
depends=('mingw-w64-clang-aarch64-zlib')
makedepends=('mingw-w64-clang-aarch64-configure')
license=('custom')
url="http://www.libpng.org/pub/png/libpng.html"
options=('!strip' '!buildflags' 'staticlibs')
source=("https://downloads.sourceforge.net/sourceforge/libpng/libpng-$pkgver.tar.xz")
sha256sums=('60c4da1d5b7f0aa8d158da48e8f8afa9773c1c8baa5d21974df61f1886b8ce8e')

_architectures="aarch64-w64-mingw32"

prepare() {
  cd "$srcdir/libpng-$pkgver"

  # autoreconf to get updated libtool files with clang support
  autoreconf -fiv

  sed -i -e 's|x86 archive import|archive import|g' configure
}

build() {
  export USE_COMPILER_WRAPPERS=1
  cd "$srcdir/libpng-$pkgver"
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    mkdir -p build-${_arch} && pushd build-${_arch}
    ${_arch}-configure
    make
    popd
  done
}

package () {
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    cd "${srcdir}/libpng-${pkgver}/build-${_arch}"
    make install DESTDIR="${pkgdir}"
    rm -r "${pkgdir}"/usr/${_arch}/share
    rm "${pkgdir}"/usr/${_arch}/bin/*.exe
    $STRIP --strip-unneeded "${pkgdir}"/usr/${_arch}/bin/*.dll
    $STRIP -g "${pkgdir}"/usr/${_arch}/lib/*.a
  done
}
