pkgname=mingw-w64-clang-aarch64-libxml2
pkgver=2.14.5
pkgrel=1
arch=('any')
pkgdesc='XML C parser and toolkit (mingw-w64-clang-aarch64)'
url='https://gitlab.gnome.org/GNOME/libxml2/-/wikis/home'
depends=('mingw-w64-clang-aarch64-crt' 'mingw-w64-clang-aarch64-libiconv' 'mingw-w64-clang-aarch64-zlib' 'mingw-w64-clang-aarch64-xz')
makedepends=('git' 'mingw-w64-clang-aarch64-configure')
options=('!buildflags' '!strip' 'staticlibs')
license=(MIT)
# using GitHub mirror as https://gitlab.gnome.org/GNOME/libxml2.git seems broken right now
source=("git+https://github.com/GNOME/libxml2.git#tag=v$pkgver")
b2sums=('c4104e9f98671c591df9bd539c24c5dd232644750c3e8ec1664592638b01f61148150d44c50f919eacf4b63750a486ec87b4a5a65535d2872d42c7d9c9fd768a')

_architectures="aarch64-w64-mingw32"

prepare () {
  cd libxml2

  # avoid `ld.lld: error: unknown argument '--enable-auto-image-base'` when using LLVM-based toolchain
  [[ $pkgname =~ .*-clang-.* ]] && \
    find . -name 'libtool.m4' -exec sed -i -e 's|$wl--enable-auto-image-base||g' {} \+

  # Revert bad Python fix
  # https://gitlab.gnome.org/GNOME/libxml2/-/issues/917
  git revert -n 381fb50113660418fb3520bde64084ecf122bf88

  # disable doc & examples
  sed -i "s| doc example | |g" Makefile.am
  autoreconf -vfi
}

build() {
  export USE_COMPILER_WRAPPERS=1
  cd libxml2

  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    mkdir -p build-${_arch} && pushd build-${_arch}
    ${_arch}-configure --without-python
    make
    popd
  done
}

package() {
  export USE_COMPILER_WRAPPERS=1
  cd libxml2
  install -Dm644 Copyright -t "$pkgdir/usr/share/licenses/$pkgname"

  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    cd "${srcdir}/libxml2/build-${_arch}"
    make install DESTDIR="${pkgdir}"
    rm "${pkgdir}"/usr/${_arch}/bin/*.exe
    $STRIP --strip-unneeded "${pkgdir}"/usr/${_arch}/bin/*.dll
    $STRIP --strip-debug "${pkgdir}"/usr/${_arch}/lib/*.a
  done
}

