_pkgname=pcre2
pkgname=mingw-w64-clang-aarch64-$_pkgname
pkgver=10.44
pkgrel=1
pkgdesc='A library that implements Perl 5-style regular expressions. 2nd version (mingw-w64-clang-aarch64)'
arch=('any')
url='https://www.pcre.org/'
license=('BSD')
makedepends=(mingw-w64-clang-aarch64-configure mingw-w64-clang-aarch64-readline mingw-w64-clang-aarch64-bzip2 mingw-w64-clang-aarch64-zlib)
depends=(mingw-w64-clang-aarch64-crt)
options=(staticlibs !strip !buildflags)
optdepends=(mingw-w64-clang-aarch64-readline mingw-w64-clang-aarch64-bzip2 mingw-w64-clang-aarch64-zlib)
source=("https://github.com/PhilipHazel/$_pkgname/releases/download/$_pkgname-$pkgver/$_pkgname-$pkgver.tar.bz2"{,.sig})
sha512sums=('ee91cc10a2962bc7818b03d368df3dd31f42ea9a7260ae51483ea8cd331b7431e36e63256b0adc213cc6d6741e7c90414fd420622308c0ae3fcb5dd878591be2'
            'SKIP')
validpgpkeys=('45F68D54BBE23FB3039B46E59766E084FB0F43D8')  # Philip Hazel

_architectures="aarch64-w64-mingw32"

prepare() {
  cd "$srcdir/$_pkgname-$pkgver"
}

build() {
  export USE_COMPILER_WRAPPERS=1
  cd "$srcdir/$_pkgname-$pkgver"
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    mkdir -p build-${_arch} && pushd build-${_arch}
    ${_arch}-configure \
      --enable-jit \
      --enable-pcre2-16 \
      --enable-pcre2-32 \
      --enable-pcre2grep-libz \
      --enable-pcre2grep-libbz2 \
      --enable-pcre2test-libreadline
    make
    popd
  done
}

package() {
  export USE_COMPILER_WRAPPERS=1
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    cd "${srcdir}/${pkgname##mingw-w64-clang-aarch64-}-$pkgver/build-${_arch}"
    make DESTDIR="$pkgdir" install
    rm -r "$pkgdir/usr/${_arch}/share/"{man,doc}
    find "$pkgdir/usr/${_arch}" -name '*.exe' -exec $STRIP {} \;
    find "$pkgdir/usr/${_arch}" -name '*.dll' -exec $STRIP --strip-unneeded {} \;
    find "$pkgdir/usr/${_arch}" -name '*.a' -o -name '*.dll' | xargs $STRIP -g
  done
}
