# Maintainer: jazztickets <jazztickets at gmail dot com>
# Contributor: Andrew Sun <adsun701 at gmail dot com>
# Contributor: napa3um <napa3um at gmail dot com>
# Contributor: Filip Brcic <brcha at gna dot org>

pkgname=mingw-w64-clang-aarch64-sqlite
_amalgamationver=3460100
pkgver=3.46.1
pkgrel=1
pkgdesc="A C library that implements an SQL database engine (mingw-w64-clang-aarch64)"
arch=('any')
groups=(mingw-w64-clang-aarch64)
depends=('mingw-w64-clang-aarch64-crt')
makedepends=('mingw-w64-clang-aarch64-configure' 'mingw-w64-clang-aarch64-pdcurses' 'mingw-w64-clang-aarch64-readline')
options=('!buildflags' '!strip' 'staticlibs')
license=('custom:Public Domain')
url="https://www.sqlite.org/"
source=("https://www.sqlite.org/2024/sqlite-autoconf-${_amalgamationver}.tar.gz")
sha256sums=('67d3fe6d268e6eaddcae3727fce58fcc8e9c53869bdd07a0c61e38ddf2965071')

_architectures="aarch64-w64-mingw32"

build() {
  export USE_COMPILER_WRAPPERS=1
  cd "${srcdir}/sqlite-autoconf-${_amalgamationver}"
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    mkdir -p build-${_arch} && pushd build-${_arch}
    CFLAGS+=" -fexceptions -DSQLITE_ENABLE_COLUMN_METADATA=1 -DSQLITE_USE_MALLOC_H=1 -DSQLITE_USE_MSIZE=1 -DSQLITE_DISABLE_DIRSYNC=1 -DSQLITE_ENABLE_RTREE=1 -fno-strict-aliasing"
    config_TARGET_EXEEXT=.exe \
    ${_arch}-configure \
      --enable-threadsafe \
      --disable-editline \
      --enable-readline \
      --enable-fts3 \
      --enable-fts4 \
      --enable-fts5 \
      --enable-rtree \
      --enable-json1 \
      --enable-session
    make
    popd
  done
}

package() {
  export USE_COMPILER_WRAPPERS=1
  cd "${srcdir}/sqlite-autoconf-${_amalgamationver}"
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    pushd build-${_arch}
    make DESTDIR="${pkgdir}" install
    rm -r "${pkgdir}/usr/${_arch}/share"
    $STRIP --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.exe
    $STRIP --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
    $STRIP -g "$pkgdir"/usr/${_arch}/lib/*.a
    popd
  done
}
