# Maintainer of AUR version: Patrick Northon <northon_patrick3@yahoo.ca>

_pkgname=vulkan-headers
pkgname=mingw-w64-clang-aarch64-${_pkgname}
_dirname=Vulkan-Headers
pkgver=1.4.309.0
pkgrel=1
pkgdesc='Vulkan header files (mingw-w64-clang-aarch64)'
arch=(any)
url="https://www.vulkan.org/"
license=("Apache-2.0 OR MIT")
makedepends=(mingw-w64-clang-aarch64-cmake ninja git)
groups=('mingw-w64-clang-aarch64-vulkan-devel')
options=(!buildflags staticlibs !strip)
source=("git+https://github.com/KhronosGroup/Vulkan-Headers#tag=vulkan-sdk-$pkgver")
b2sums=('d4703fab34991fd81e5c44c7ba5aa15aca30dacc6ddfec82972cda16e8598e0c8180d4612adca9063efc57b1f32c87f11c3e8f6e87df7b4785d055e0f441ea68')

_srcdir="${_dirname}"
_architectures='aarch64-w64-mingw32'

build() {
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    ${_arch}-cmake -G Ninja -S "${_srcdir}" -B "build-${_arch}"
    cmake --build "build-${_arch}"
  done
}

package() {
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    DESTDIR="${pkgdir}" cmake --install "build-${_arch}"
  done
  install -Dm644 Vulkan-Headers/LICENSES/MIT.txt \
    -t "$pkgdir/usr/share/licenses/$pkgname"
}
